Listado de medidas y su expresión en Power BI

En este artículo vamos a demostrar como obtener el listado de medidas y su expresión en Power BI de un modelo semántico con las nuevas funcionalidades que nos trae Power BI en su versión de Diciembre de 2023 como son las fórmulas DAX INFO. Sigue leyendo por que te puede ser de gran utilidad ¡no utilizaremos ninguna herramienta externa!

Especificaciones del entorno

• Windows 11
• Power BI Desktop (Diciembre 2023)

Objetivo final

El objetivo de este artículo es mostrar por pantalla un listado de las medidas junto a su expresión. Podrás copiar los resultados y mejorar tu documentación o encontrar duplicidades.

Obtener el listado paso a paso

Para poder conseguir este listado necesitamos obtener información de diferentes tablas lanzando diferentes consultas DAX y después unirlas para mostrar la información resumida. Veamos paso por paso como conseguirlo gracias a la vista de consulta DAX de Power BI Desktop.

Obtener el listado de medidas

El primer paso es construir nuestra fórmula DAX para obtener el listado de todas las medidas de nuestro modelo semántico. Para conseguirlo crearemos una variable llamada _medidas y seleccionamos las columnas Name, Expression y TableID y le asignaremos un nombre a cada campo. Esto lo conseguimos gracias a la función INFO.MEASURES.

EVALUATE
    VAR _medidas = 
        SELECTCOLUMNS(
            INFO.MEASURES(),
            "Medida", [Name],
            "DAX formula", [Expression],
            "ID-Tabla", [TableID]
        )
    RETURN
            _medidas

Escribe la consulta DAX anterior en la vista de consultas y ejecutala. Recuerda que desde esta versión puedes utilizar la tecla F5 para ejecutar la consulta. Al ejecutarlo, podremos ver el nombre de todas las medidas del modelo semántico, su expresión y el identificador de la tabla donde está almacenada.

Obtener el listado de tablas

En la consulta anterior has visto como obtenemos el ID de la tabla pero no sabemos su nombre. Para averiguarlo utilizamos la función INFO.TABLES. Escribe esta nueva consulta donde creamos una variable _tablas para leer el nombre de la tabla y su identificador (puedes pulsar en nueva consulta en el margen inferior izquierda de Power BI Desktop para no perder la anterior consulta)

EVALUATE
    VAR _tablas = 
        SELECTCOLUMNS(
            INFO.TABLES(),
            "ID-Tabla", [ID],
            "Tabla", [Name]
        )
    RETURN
            _tablas

Unir resultados

Ahora que por un lado tenemos el listado de medidas y por otro el listado de tablas, nos toca unir ambos resultados. Lo vamos a conseguir gracias a NATURALLEFTOUTERJOIN y después indicaremos que campos queremos que nos muestre por pantalla en el RETURN. El código completo es el siguiente:

EVALUATE
    VAR _medidas = 
        SELECTCOLUMNS(
            INFO.MEASURES(),
			"ID-Tabla", [TableID],
            "Medida", [Name],
            "DAX formula", [Expression]
        )
    VAR _tablas = 
        SELECTCOLUMNS(
            INFO.TABLES(),
            "ID-Tabla", [ID],
            "Tabla", [Name]
        )
    VAR _combinadas = 
        NATURALLEFTOUTERJOIN(_medidas, _tablas)
    RETURN
        SELECTCOLUMNS(
            _combinadas,
            "Tabla", [Tabla],
			"Medida", [Medida],
            "DAX Formula", [DAX formula]
        )

Ya tienes la relación entre las consultas DAX y tienes un listado de tablas y medidas junto a su expresión. Utiliza el botón Copia para llevártelo a un excel o a una tabla con la opción especificar datos.

Automatizar la actualización de datos

Por desgracia a día de redacción de este artículo no es posible automatizar esta consulta desde el propio Power BI Desktop, pero tenemos otra herramienta muy útil, Power Automate. Lee este artículo para descubrir cómo automatizar esta consulta.